Calcular depreciación con Excel – Segunda nota

viernes, mayo 02, 2008

En la primer nota del tema vimos las distintas funciones que Excel pone a nuestra disposición para calcular la depreciación de un bien.
En esta nota veremos cómo construir una tabla, o cédula, de depreciación para todos los bienes de una empresa imaginaria. Esta tabla debe asistirnos en el cálculo de total del monto de depreciación que será reconocido como gasto en el cuadro de ganancias y pérdidas de la empresa del período.
Nuestro modelo, que calcula la depreciación de los bienes sobre una base mensual usando el método lineal, es el siguiente




La celda B1 contiene la fecha en base a la cual queremos calcular la depreciación. Aquí ponemos el último día del mes en cuestión. El modelo calcula el total de la depreciación a reconocer para el mes en la celda B2. Esta celda contiene la fórmula =SUMA(Depreciación_del_período)

Donde "Depreciación_del_período" es el nombre que contiene el rango dinámico

=DESREF('con auxiliares'!$F$5,0,0,CONTARA('con auxiliares'!$F:$F)-1,1)

Esto nos permite que el total tome en cuenta los bienes que vayamos agregando en la tabla.

Los campos Descripción, Fecha de adquisición, % de depreciación anual y valor residual son los datos de nuestro modelo. Hay que prestar atención que el porcentaje de depreciación es introducido en términos anuales, pero los cálculos serán realizados por mes.

Para realizar los cálculos podemos adoptar dos técnicas: con o sin tablas auxiliares. En esta nota mostraremos las dos soluciones, pero sin entrar a considerar cuál es el método más apropiado.

Dado que usamos el método lineal, calculamos la depreciación del período (mes) con la función SLN. Para calcular los períodos transcurridos desde la adquisición de los bienes, usaremos la función SIFECHA.
Aquí tenemos que tomar en cuenta que existe la posibilidad de que uno o más bienes hayan sido depreciados (amortizados) completamente. Para evaluar esta posibilidad creamos una tabla auxiliar



En la columna J (Total de meses) usamos la fórmula =1/D5*12. Esto nos da el total de meses de vida útil del bien.

En la columna K (Transcurridos) usamos la fórmula =SIFECHA(B5,$B$1,"m"), que calcula la cantidad de meses transcurridos desde la adquisición del bien, incluido el mes del cálculo.

La columna L (Restantes) nos da la diferencia entre J y K. Este resultado será nuestro indicador si el bien debe ser depreciado o no. En caso de ser negativo, el bien ha sido depreciado en su totalidad.

Una vez construida la tabla auxiliar, ponemos las fórmulas en para nuestros cálculos:

Depreciación del período (F): =SI(L5>0,SLN(C5,E5,1/D5*12),0)

Depreciación acumulada (G): =SI(L5>0,SIFECHA(B5,$B$1,"m")*F5,C5-E5)

Saldo (H): obviamente =C5-G5

Si queremos construir nuestro modelo sin tablas auxiliares, lo que hacemos es crear fórmulas que incluyas las auxiliares. En la hoja "sin auxiliares" del archivo con el ejemplo pueden ver la aplicación de estas fórmulas

Depreciación del período (F): =SI((1/D5*12-SIFECHA(B5,$B$1,"m"))>0,SLN(C5,E5,1/D5*12),0)

Depreciación acumulada (G): =SI((1/D5*12-SIFECHA(B5,$B$1,"m"))>0,SIFECHA(B5,$B$1,"m")*F5,C5-E5)



Un punto a tomar en cuenta es que hacemos los cálculos por meses enteros. Es decir, la antigüedad de un bien es la misma sin importar en que día del mes haya sido adquirido.
En algunos sistemas se considera el primer mes como completo sólo si el bien ha sido adquirido (o puesto en marcha) antes del día 15 del mes.
En la hoja "con auxiliares (2)" hemos modificado la fórmula de la columna K (Transcurridos) de manera que la cuenta de meses se haga de acuerdo a esta regla:

=SI(DIA(B5)<15,SIFECHA(B5,$B$1,"m"),SIFECHA(B5,$B$1,"m")-1)

Otro punto a tomar en cuenta es que si la fecha en B1 es anterior a la fecha de adquisición de un bien, las fórmulas que se refieren a el darán un resultado #NUM!. Esta situación podría darse si queremos calcular el total de la depreciación en un período del pasado.
En este modelo he optado por el uso de Formato condicional para volver "invisible" el contenido de las celdas que dan un resultado de error




También tenemos que modificar la fórmula en la celda B2, para obtener el total sin errores. Para esto usaremos la técnica mostrada en la nota sobre operaciones con rangos que contienen errores. En nuestro caso ponemos esta fórmula matricial

={SUMA(SI(ESERROR(Depreciación_del_período),0,Depreciación_del_período))}



Todo esto se puede ver en la hoja "con auxiliares (3)" del cuaderno con el ejemplo.



Technorati Tags:

10 comments:

Lucas 02 mayo, 2008 16:14  

Hola Jorge, soy un usuario novato de excel y a veces me ocurre que al restar valores iguales me aparece -0 ¿Me podrías indicar porque ocurre esto?

Jorge L. Dunkelman 02 mayo, 2008 18:19  

Hola Lucas

Excel, y la mayoría de los programas, guarda los números em forma binaria (en términos de 1 y 0). Esto crea un problema de precisión (punto flotante) en ciertas situaciones, como parece ser la tuya. Puedes leer esta nota del blog sobre el tema. Allí encontrarás enlaces a notas de Microsoft y de Chip Pearson (ésta en inglés), si quieres ampliar sobre el tema.

Jack 06 mayo, 2008 04:02  

Hoja Jorge, quiero fecilitarte por tu gran trabajo, sin embargo quiero me que ayudes con esta duda;

En la depreciación del periodo, solo me dice cuanto voy a depreciar en ese mes, es decir al 30/04/2008 pero yo quiero saber cuanto es la depreciación del periodo del año, es decir 12 meses, para ver si lo que esta registrado en la contabilidad es lo correcto a esta tabla. con las siguientes variantes:
-Bien A: vida útil 24 meses, al 30/04/2008 ya tiene 40 meses, es decir en mis 12 meses no hay depreciación del periodo.
-Bien B: vida útil 36 meses al 30/04/2008 ya tiene 40 meses, ósea en el periodo de 12 meses solo le voy a calcular 8.
.Bien C: vida útil 36 meses,, al 30/04/2008 ya tiene 5 meses.

y que estás variantes tambien apliquen a la depreciación acumulada.

Espero que puedas aclararme esta inquietud...y gracias!

Jack López
jkazz@hotmail.com

Jorge L. Dunkelman 06 mayo, 2008 20:44  

Hola Jack
como comprenderás una respuesta a tus inquietudes excedería el marco de un comentario.
Estoy preparando una nota ampliando el modelo de depreciación. Tus inquietudes erán tomadas en cuenta.

Jack 06 mayo, 2008 21:03  

Hola Jorge

Gracias por tu apoyo, estaré atento a tu respuesta.

Un saludo cordial

Jack López

CITIVAN 28 diciembre, 2008 22:29  

hola jorge, mi nombre es ivan y soy profesor. Estoy haciendo mi registro de notas en excel, pero no puedo recordar como hago para que cuando aun no se han introducido calificaciones no aprezcan valores de cero o ## en las celdas que tienen formula, te agradecere bastante tu ayuda o en todo caso si necesitas ver mi registro dime como enviarlo para que lo analices. Gracias de antemano y dejame decirte que ha sido un gran hallazgo haber encontrado tu pagina

Jorge L. Dunkelman 29 diciembre, 2008 21:08  

Hola
por lo general cunado aparece una serie de # en una celda significa que el ancho de la columna es insuficiente para mostrar el contenido de la celda.
Para que no aparezcan ceros puedes abrir el menú Herramientas-Opciones y en la pestaña Ver quitar al marca de la casilla Valores cero.

Anónimo,  13 septiembre, 2012 00:22  

Hola que pasa cuando una empresa no a realizado depreciacion de ninguno de los vehiculos que posee durante tiene de existir como entidad anonima. Es decir como calcular la depreciacion actual.

Jorge L. Dunkelman 13 septiembre, 2012 08:52  

Depende de lo que establezcan las normas o leyes del país en cuestión. Fuera de eso, sencillamente sería "depreciación anual X años"

Roger Baldeon 27 octubre, 2012 20:28  

Gracias, Jorge.
Me ayudaste a entender un poco mas del tema.

Slds,
Roger

Publicar un comentario

Google+ Followers

Seguidores

Google+ Badge

Términos Legales

  © Blogger template On The Road by Ourblogtemplates.com 2009

Back to TOP